source: Include/Classes/System/Drawing/PointF.ab@ 1

' Classes/System/Drawing/PointF.ab

#ifndef __SYSTEM_DRAWING_POINTF_AB__
#define __SYSTEM_DRAWING_POINTF_AB__

#include <Classes/System/Drawing/Size.ab>
#include <Classes/System/Drawing/SizeF.ab>

Class PointF
Public
    Sub PointF()
        x = 0
        y = 0
    End Sub

    Sub PointF(initX As Single, initY As Single)
        x = initX
        y = initY
    End Sub

    Sub PointF(ByRef pt As PointF)
        x = pt.x
        y = pt.y
    End Sub

    Sub PointF(ByRef sz As SizeF)
        x = sz.Width
        y = sz.Height
    End Sub

    Function X() As Single
        Return x
    End Function

    Sub X(newX As Single)
        x = newX
    End Sub

    Function Y() As Single
        Return y
    End Function

    Sub Y(newY As Single)
        y = newY
    End Sub

    Function IsEmpty() As BOOL
        If x = 0 And y = 0 Then
            Return _System_TRUE
        Else
            Return _System_FALSE
        End If
    End Function

    Sub Operator = (ByRef pt As PointF)
        x = pt.x
        y = pt.y
    End Sub

    Function Operator + (pt As PointF) As PointF
        Return Add(pt)
    End Function

    Function Operator + (sz As Size) As PointF
        Return Add(sz)
    End Function

    Function Operator + (sz As SizeF) As PointF
        Return Add(sz)
    End Function

    Function Operator - (pt As PointF) As PointF
        Return Substract(pt)
    End Function

    Function Operator - (sz As Size) As PointF
        Return Substract(sz)
    End Function

    Function Operator - (sz As SizeF) As PointF
        Return Substract(sz)
    End Function

    Function Operator == (sz As PointF) As BOOL
        Return Equals(sz)
    End Function

    Function Operator <> (sz As PointF) As BOOL
        Return Not Equals(sz)
    End Function

    Function Add(pt As PointF) As PointF
        Dim ret As PointF(x + pt.x, y + pt.y)
        Return ret
    End Function

    Function Add(sz As Size) As PointF
        Dim ret As PointF(x + sz.width, y + sz.height)
        Return ret
    End Function

    Function Add(sz As SizeF) As PointF
        Dim ret As PointF(x + sz.width, y + sz.height)
        Return ret
    End Function

    Function Substract(pt As PointF) As PointF
        Dim ret As PointF(x - pt.x, y - pt.y)
        Return ret
    End Function

    Function Substract(sz As Size) As PointF
        Dim ret As PointF(x - sz.width, y - sz.height)
        Return ret
    End Function

    Function Substract(sz As SizeF) As PointF
        Dim ret As PointF(x - sz.width, y - sz.height)
        Return ret
    End Function

    Function Equals(pt As PointF) As BOOL
        If x = pt.x And y = pt.y Then
            Equals = _System_TRUE
        Else
            Equals = _System_FALSE
        End If
    End Function

Private
    x As Single
    y As Single
End Class

#endif '__SYSTEM_DRAWING_POINTF_AB__